Breaking News: Grepper is joining You.com. Read the official announcement!

size files folders MB batch vbscript convertbytes MB GB TB

Hackoo Crackoo answered on September 29, 2022 Popularity 2/10 Helpfulness 8/10

answer size files folders MB batch vbscript convertbytes MB GB TB

size files folders MB batch vbscript convertbytes MB GB TB

Comment

@echo off
Title Script For Getting Folder Sizes
echo Getting folder sizes for you...
setlocal disabledelayedexpansion
Set "VBS=%Temp%\ConvertSize.vbs"
set "folder=%~1"
if not defined folder set "folder=%cd%"
@for /d %%a in ("%folder%\*") do (
    set "size=0"
    @for /f "tokens=3,5" %%b in (
        'dir /-c /a /w /s "%%~fa\*" 2^>nul ^| findstr /b /c:"  "'
    ) do (
        if "%%~c"=="" set "size=%%~b"
    )
    setlocal enabledelayedexpansion
    call :ConvertBytes !size! unit 
    echo(%%~nxa ==^> !unit!
    endlocal 
)
endlocal
pause
exit /b
::-------------------------------------------------------
:ConvertBytes <Size> <Unit>
(
    echo wscript.echo Convert("%~1"^)
    echo 'Function to format a number into typical size scales
    echo Function Convert(iSize^)
    echo    aLabel = Array("bytes", "KB", "MB", "GB", "TB"^)
    echo    For i = 0 to 4
    echo        If iSize ^> 1024 Then
    echo            iSize = iSize / 1024
    echo        Else
    echo            Exit For
    echo        End If
    echo    Next
    echo    Convert = Round(iSize,2^) ^& " " ^& aLabel(i^)
    echo End Function
)>"%VBS%"
for /f "delims=" %%a in ('Cscript //NoLogo "%VBS%"') do ( set "%2=%%a" )
Exit /b
::-------------------------------------------------------

Popularity 2/10 Helpfulness 8/10 Language shell

Source: stackoverflow.com

Tags: shell size vbscript

Link to this answer
Share Copy Link

Contributed on Sep 29 2022

Hackoo Crackoo

0 Answers Avg Quality 2/10

size files folders MB batch vbscript convertbytes MB GB TB

Contents

More Related Answers

size files folders MB batch vbscript convertbytes MB GB TB

Grepper

Documentation

Social

Legal

Contact

Oops, You will need to install Grepper and log-in to perform this action.